sdk/samples/all in on code/Visual Studio 2008/VBSparseFile/MainModule.vb

   1 '****************************** Module Header ******************************'
   2 ' Module Name:  MainModule.vb
   3 ' Project:      VBSparseFile
   4 ' Copyright (c) Microsoft Corporation.
   5 '
   6 ' VBSparseFile demonstrates the common operations on sparse files. A sparse
   7 ' file is a type of computer file that attempts to use file system space more
   8 ' efficiently when blocks allocated to the file are mostly empty. This is
   9 ' achieved by writing brief information (metadata) representing the empty
  10 ' blocks to disk instead of the actual "empty" space which makes up the
  11 ' block, using less disk space. You can find in this example the creation of
  12 ' sparse file, the detection of sparse attribute, the retrieval of sparse
  13 ' file size, and the query of sparse file layout.
  14 '
  15 ' This source is subject to the Microsoft Public License.
  16 ' See http://www.microsoft.com/opensource/licenses.mspx#Ms-PL.
  17 ' All other rights reserved.
  18 '
  19 ' History:
  20 ' * 7/7/2009 11:34 PM Jialiang Ge Created
  21 '***************************************************************************'
  22
  23 #Region "Imports directives"
  24
  25 Imports System.IO
  26
  27 #End Region
  28
  29
  30 Module MainModule
  31
  32     Sub Main()
  33
  34         '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
  35         ' Determine if the volume support sparse streams.
  36         '
  37
  38         If Not SparseFile.VolumeSupportsSparseFiles("C:\") Then
  39             Console.WriteLine("Volume {0} does not support sparse streams", _
  40                               "C:\")
  41             Return
  42         End If
  43
  44
  45         '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
  46         ' Create a sparse file.
  47         '
  48
  49         Dim fileName As String = "SparseFile.tmp"
  50         Console.WriteLine("Create sparse file: {0}", fileName)
  51
  52         Using fs As FileStream = SparseFile.Create(fileName)
  53
  54             ' Write a large block of data
  55             Const blockLength As Integer = 512 * 1024 ' 512KB
  56             Dim block As Byte() = New Byte(blockLength - 1) {}
  57             For i As Integer = 0 To blockLength - 1
  58                 block(i) = &HFF
  59             Next i
  60
  61             fs.Write(block, 0, blockLength)
  62
  63             ' Set some sparse ranges in the block
  64
  65             SparseFile.SetSparseRange(fs.SafeFileHandle, 0, &H10000)
  66             SparseFile.SetSparseRange(fs.SafeFileHandle, &H20000, &H20000)
  67
  68             ' Set sparse block at the end of the file
  69
  70             ' 1GB sparse zeros are extended to the end of the file
  71             fs.SetLength(fs.Length + &H40000000)
  72
  73         End Using
  74
  75
  76         '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
  77         ' Determine if a file is sparse.
  78         '
  79
  80         Dim isSparse As Boolean = SparseFile.IsSparseFile(fileName)
  81         Console.WriteLine("The file is{0} sparse", IIf(isSparse, "", " not"))
  82
  83
  84         '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
  85         ' Get file size.
  86         '
  87
  88         SparseFile.GetSparseFileSize(fileName)
  89
  90
  91         '''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
  92         ' Query the sparse file layout.
  93         '
  94
  95         SparseFile.GetSparseRanges(fileName)
  96
  97     End Sub
  98
  99 End Module